# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit desktop xdg

DESCRIPTION="Powerful modern download accelerator and organizer"
HOMEPAGE="https://www.freedownloadmanager.org/"
# Upstream only provides a "latest" URL, bump PV along with the DEB contents.
SRC_URI="https://files2.freedownloadmanager.org/6/latest/freedownloadmanager.deb -> ${P}.deb"

S="${WORKDIR}"

LICENSE="all-rights-reserved"
SLOT="0"
KEYWORDS="~amd64"

RESTRICT="mirror"

QA_PREBUILT="/opt/${PN}/*"

# Optional plugins with sonames not available in Gentoo
REQUIRES_EXCLUDE="
	libclntsh.so.23.1
	libfbclient.so.2
	libmimerapi.so
	libmysqlclient.so.21
	libodbc.so.2
	libpq.so.5
	libtiff.so.5
"

RDEPEND="
	app-arch/bzip2
	app-arch/zstd
	app-crypt/mit-krb5
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/openssl
	media-libs/fontconfig
	media-libs/freetype
	media-libs/libpng
	media-libs/libpulse
	media-libs/libsndfile
	media-video/ffmpeg
	sys-apps/bubblewrap
	virtual/opengl
	x11-libs/gtk+:3
	x11-libs/libX11
	x11-libs/libxcb
	x11-libs/libxkbcommon
	x11-libs/xcb-util-cursor
	x11-libs/xcb-util-keysyms
	x11-libs/xcb-util-wm
	x11-misc/xdg-utils
"

src_unpack() {
	ar x "${DISTDIR}/${P}.deb" || die
	unpack ./data.tar.xz
}

src_install() {
	insinto "/opt/${PN}"
	doins -r opt/freedownloadmanager/*
	fperms 755 "/opt/${PN}/fdm" "/opt/${PN}/wenativehost"

	dosym ../../opt/${PN}/fdm /usr/bin/${PN}

	sed -e "s|/opt/freedownloadmanager|/opt/${PN}|" \
		usr/share/applications/freedownloadmanager.desktop \
		> "${T}/freedownloadmanager.desktop" || die
	domenu "${T}/freedownloadmanager.desktop"

	newicon -s 256 opt/freedownloadmanager/icon.png freedownloadmanager.png

	insinto /usr/share/metainfo
	doins usr/share/appdata/freedownloadmanager.appdata.xml
}