# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /proj/FAUmachine/FAUmachine/scripts/faumachine-VERSION.ebuild,v 1.13 2006/03/16 11:46:51 sihoschi Exp $

DESCRIPTION="An Open Source virtual machine"
SRC_URI="http://www3.informatik.uni-erlangen.de/Research/FAUmachine/${PV}/${P}.tar.gz"
HOMEPAGE="http://www.faumachine.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc stats"

RDEPEND=">=x11-libs/gtk+-2"
DEPEND="${RDEPEND}
	doc? (
		app-text/tetex
		media-gfx/transfig
		app-text/psutils
		virtual/ghostscript
	)"

src_unpack() {
	unpack ${A}

	# fix for a Makefile race condition
	# (can be removed with next release after 20060310)
	grep -Fv 'all: faum-confwizard' "${S}/configwizard/Makefile.am" \
		> "${S}/configwizard/Makefile.am.new" \
	&& mv "${S}/configwizard/Makefile.am.new" "${S}/configwizard/Makefile.am"
}

src_compile() {
	local myconf=

	# create configure parameters according to USE flags
	myconf="${myconf} $(use_enable doc build-userguide)"
	myconf="${myconf} $(use_enable stats statistics)"

	# needed to avoid qt/uic sandbox violations
	# (cf. Gentoo bug reports #29889, #45658)
	addwrite "${QTDIR}/etc/settings"

	econf \
		--mandir=/usr/share/man \
		--infodir=/usr/share/info \
		--disable-prefix-search \
		--enable-shared \
		${myconf} \
		|| die "Configure failed"

	emake || die "Compile failed"
}

src_install() {
	make DESTDIR="${D}" install || die "Install failed"
}