# Copyright 2025-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake

DESCRIPTION="The embeddable expression engine fork for Krita"
HOMEPAGE="https://invent.kde.org/graphics/kseexpr"

if [[ ${PV} == "9999" ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://invent.kde.org/graphics/seexpr.git"
else
	KEYWORDS="~amd64 ~x86"
	SRC_URI="https://invent.kde.org/graphics/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
	S="${WORKDIR}/${PN}-v${PV}"
fi

LICENSE="GPL-3+"
SLOT="0/6"
IUSE="+doc test"
RESTRICT="!test? ( test )"

DEPEND="
	dev-qt/qtbase:6[dbus,gui,widgets]
	dev-qt/qttools:6[linguist,qdbus,widgets]
	kde-frameworks/ki18n:6"
RDEPEND="${DEPEND}"
BDEPEND="
	sys-devel/bison
	sys-devel/flex
	doc? ( app-text/doxygen )
	test? ( dev-cpp/gtest media-libs/libpng )"
PDEPEND="media-gfx/krita:0[kseexpr(-)]"

src_configure() {
	local mycmakeargs=(
		"-DENABLE_QT6=true"

		"-DENABLE_LLVM_BACKEND=false" # heavily bitrotted
		"-DENABLE_PERFORMANCE_STATS=false" # doesn't compile

		# /usr/share/KSeExpr/utils/{eval,listVar} binaries; these aren't very useful
		"-DBUILD_UTILS=false"

		# Demos include /usr/bin/imageSynth2 (.se -> .png CLI converter)
		# There's an entire GUI in here too, but it only builds with Qt5.
		"-DBUILD_DEMOS=true"

		# Mostly API docs, but also an HTML syntax reference for offline reading.
		"-DBUILD_DOC=$(usex doc)"

		"-DBUILD_TESTS=$(usex test)"
		"-DENABLE_SLOW_TESTS=$(usex test)"

		"-DUSE_PREGENERATED_FILES=false"
		"-DBUILD_TRANSLATIONS=true"
	)
	cmake_src_configure
}