# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

WX_GTK_VER=2.8
inherit cmake-utils wxwidgets db-use multilib eutils

MY_P=${P/trustedqsl/tqsl}
DESCRIPTION="Log signing for the ARRL Logbook of the World (LoTW)"
HOMEPAGE="http://www.arrl.org/logbook-of-the-world"
SRC_URI="http://www.arrl.org/files/file/LoTW%20Instructions/${MY_P}.tgz"

LICENSE="TrustedQSL"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

DEPEND="
	dev-libs/openssl:0
	dev-libs/expat
	net-misc/curl
	>=sys-libs/db-5.3
	sys-libs/zlib
	x11-libs/wxGTK:2.8[X]
"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}

# Include LICENSE.txt for binary distribution
# Full copyright notice doesn't seem to be included otherwise
DOCS=(AUTHORS.txt README LICENSE.txt)

src_configure() {
	local mycmakeargs=(
			-DBDB_LIBRARY="${EROOT}usr/$(get_libdir)/lib$(db_libname)$(get_libname)"
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	make_desktop_entry tqsl "Logbook of the World" TrustedQSL 'Office;HamRadio'
}