# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
DISTUTILS_SINGLE_IMPL=1
inherit distutils-r1 xdg-utils

DESCRIPTION="A multitrack non-linear video editor for Linux"
HOMEPAGE="http://jliljebl.github.io/flowblade/"
LICENSE="GPL-3"
SLOT="0"

if [[ ${PV} == 9999* ]]; then
	inherit git-r3
else
	KEYWORDS="~amd64"
	SRC_URI="https://github.com/jliljebl/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
fi

IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RESTRICT="test"

RDEPEND="$(python_gen_cond_dep '
	dev-python/dbus-python[${PYTHON_USEDEP}]
	dev-python/numpy[${PYTHON_USEDEP}]
	dev-python/pillow[${PYTHON_USEDEP}]
	dev-python/pycairo[${PYTHON_USEDEP}]
	dev-python/pygobject[${PYTHON_USEDEP}]
	media-libs/mlt[ffmpeg,frei0r,opencv,python,sdl,${PYTHON_SINGLE_USEDEP}] ' )
	gnome-base/librsvg[introspection]
	media-gfx/gmic
	x11-libs/gtk+:3[introspection]
	${PYTHON_DEPS}
"

DEPEND="${RDEPEND}"

src_prepare() {
	sed -i \
		-e "s#/usr/share/flowblade/#$(python_get_sitedir)/#g" \
		"${S}/flowblade-trunk/flowblade" || die

	default
}

src_compile() {
	cd "${S}/flowblade-trunk" || die
	distutils-r1_src_compile
}

src_install() {
	cd "${S}/flowblade-trunk" || die
	distutils-r1_src_install
}

pkg_postinst() {
	xdg_desktop_database_update
	xdg_mimeinfo_database_update
	xdg_icon_cache_update
}

pkg_postrm() {
	xdg_desktop_database_update
	xdg_mimeinfo_database_update
	xdg_icon_cache_update
}