# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit desktop xdg-utils

DESCRIPTION="Transmission Remote GUI is a front-end to remotely control Transmission daemon"
HOMEPAGE="https://github.com/transmission-remote-gui/transgui"
SRC_URI="https://github.com/transmission-remote-gui/transgui/archive/v${PV}.zip -> ${P}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE=""
RESTRICT="mirror strip"

DEPEND="
	>=sys-libs/glibc-2.11.0
	>=x11-libs/gtk+-2.20.0
	>=x11-libs/pango-1.28.0"
RDEPEND="${DEPEND}"
BDEPEND="
	>=dev-lang/lazarus-1.6
	>=dev-lang/fpc-2.6.2
	app-arch/unzip"

src_compile() {
	einfo "Running lazbuild"
	lazbuild -B "${S}/transgui.lpi" --lazarusdir=/usr/share/lazarus/

	einfo "Running make"
	emake || die "emake failed"
}

src_install() {
	dobin transgui

	make_desktop_entry \
		transgui \
		"Transmission remote GUI" \
		transgui \
		"Network;FileTransfer;P2P"

	doicon -s 48 transgui.png

	dodoc history.txt readme.txt LICENSE
}

pkg_postinst() {
	xdg_icon_cache_update
}

pkg_postrm() {
	xdg_icon_cache_update
}