# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="Software for processing single-crystal X-ray monochromatic diffraction data"
HOMEPAGE="https://xds.mr.mpg.de"
SRC_URI="
	https://xds.mr.mpg.de/XDS-INTEL64_Linux_x86_64.tar.gz -> XDS-INTEL64_Linux_x86_64-${PVR}.tar.gz
	https://xds.mr.mpg.de/XDS_html_doc.tar.gz -> XDS_html_doc-${PVR}.tar.gz"

LICENSE="free-noncomm"
SLOT="0"
KEYWORDS="-* ~amd64"
IUSE="doc smp"
RESTRICT="fetch"

QA_PREBUILT="opt/xds-bin/*"

# The web site uses a certificate that is not in the system certificate store.
# Use a web browser to download, instead.
pkg_nofetch() {
	elog "Please visit"
	elog "https://xds.mr.mpg.de/html_doc/downloading.html"
	elog "and download XDS-INTEL64_Linux_x86_64.tar.gz and XDS_html_doc.tar.gz."
	elog "Please save them as: ${A} in your \${DISTDIR}."
}

src_unpack() {
	default
	mv XDS-* "${S}" || die
}

src_install() {

	local i suffix=$(usex smp '_par' '')
	exeinto /opt/${PN}
	doexe *

	for i in mcolspot mintegrate xds xscale; do
		dosym ../${PN}/${i}${suffix} /opt/bin/${i}
	done

	for i in 2cbf cellparm forkxds geocorr merge2cbf pix2lab rezel xdsconv; do
		dosym ../${PN}/${i} /opt/bin/${i}
	done

	mv "${WORKDIR}/XDS_html_doc/html_doc/INPUT_templates/" "${WORKDIR}/INPUT_templates/"
	insinto "/usr/share/${PN}"
	doins -r "${WORKDIR}/INPUT_templates/"

	if use doc; then
		local HTML_DOCS=( "${WORKDIR}/XDS_html_doc/.")
		einstalldocs
		dosym -r "${EPREFIX}/usr/share/${PN}/INPUT_templates" "${EPREFIX}/usr/share/doc/${PF}/html/html_doc/INPUT_templates"
	fi
}

pkg_postinst() {
	elog "This package will expire on August 31, 2025"
}