# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi
		fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR
		pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"

inherit chromium-2 optfeature pax-utils unpacker xdg

BASE_SRC_URI="https://us-central1-apt.pkg.dev/projects/antigravity-auto-updater-dev/pool/antigravity-debian"

# See ${BASE_SRC_URI}/main/binary-${ARCH}/Packages
BUILD_ID_AMD64="1766182170"
BUILD_ID_ARM64="1766182168"
DEB_HASH_AMD64="365061c50063f9bd47a9ff88432261b8"
DEB_HASH_ARM64="940bc88042cadeaee51d9b1eedf6a506"

DESCRIPTION="Google's AI-first IDE and agentic development platform"
HOMEPAGE="https://antigravity.google/"
SRC_URI="
	amd64? ( ${BASE_SRC_URI}/antigravity_${PV}-${BUILD_ID_AMD64}_amd64_${DEB_HASH_AMD64}.deb -> ${P}_amd64.deb )
	arm64? ( ${BASE_SRC_URI}/antigravity_${PV}-${BUILD_ID_ARM64}_arm64_${DEB_HASH_ARM64}.deb -> ${P}_arm64.deb )
"
S="${WORKDIR}"

# It's complicated...
LICENSE="all-rights-reserved"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="kerberos"
RESTRICT="bindist mirror strip"

RDEPEND="
	|| (
		sys-apps/systemd
		sys-apps/systemd-utils
	)
	>=app-accessibility/at-spi2-core-2.46.0:2
	app-crypt/libsecret[crypt]
	app-misc/ca-certificates
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/nspr
	dev-libs/nss
	media-libs/alsa-lib
	media-libs/libglvnd
	media-libs/mesa
	net-misc/curl
	sys-apps/dbus
	virtual/zlib:=
	sys-process/lsof
	x11-libs/cairo
	x11-libs/gtk+:3
	x11-libs/libdrm
	x11-libs/libX11
	x11-libs/libxcb
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libxkbcommon
	x11-libs/libxkbfile
	x11-libs/libXrandr
	x11-libs/libXScrnSaver
	x11-libs/pango
	x11-misc/xdg-utils
	kerberos? ( app-crypt/mit-krb5 )
"

QA_PREBUILT="*"
QA_DESKTOP_FILE="usr/share/applications/antigravity.*\\.desktop"

# Google Chrome installs into opt/google/chrome
AG_HOME_BASE="opt/google"
AG_HOME="${AG_HOME_BASE}/antigravity"

pkg_pretend() {
	# Protect against people using autounmask overzealously
	use amd64 || use arm64 || die "Google Antigravity only works on amd64 or arm64"
}

pkg_setup() {
	chromium_suid_sandbox_check_kernel_config
}

src_install() {
	dodir /
	cd "${ED}" || die
	unpacker

	mkdir -p "${AG_HOME_BASE}" || die
	mv "usr/share/antigravity" "${AG_HOME_BASE}/" || die

	pushd "${AG_HOME}/locales" > /dev/null || die
	chromium_remove_language_paks
	popd > /dev/null || die

	rm "${AG_HOME}/resources/app/ThirdPartyNotices.txt" || die
	sed -e "/updateUrl/d" -i "${AG_HOME}/resources/app/product.json" || die

	if ! use kerberos; then
		rm -r "${AG_HOME}/resources/app/node_modules/kerberos" || die
	fi

	# Do we really need a separate MIME type for the same file?
	sed -e "s|application/x-antigravity-workspace|application/x-code-workspace|g" -i \
		usr/share/applications/*.desktop \
		usr/share/mime/packages/antigravity-workspace.xml || die

	sed -e "s|^Exec=/usr/share/antigravity/antigravity |Exec=/${AG_HOME}/antigravity |" \
		-i usr/share/applications/*.desktop || die

	mv usr/share/appdata usr/share/metainfo || die

	pax-mark m "${AG_HOME}/antigravity"
	dosym -r "/${AG_HOME}/bin/antigravity" "usr/bin/google-antigravity"
}

pkg_postinst() {
	xdg_pkg_postinst
	optfeature "desktop notifications" x11-libs/libnotify
}