# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="high-performance CUDA Library for Direct Sparse Solvers"
HOMEPAGE="https://developer.nvidia.com/cudss"
SRC_URI="
	amd64? (
		https://developer.download.nvidia.com/compute/cudss/redist/libcudss/linux-x86_64/libcudss-linux-x86_64-${PV}_cuda12-archive.tar.xz
	)
	arm64? (
		https://developer.download.nvidia.com/compute/cudss/redist/libcudss/linux-sbsa/libcudss-linux-sbsa-${PV}_cuda12-archive.tar.xz
	)
"
S="${WORKDIR}"
LICENSE="NVIDIA-cuDSS"
SLOT="0/0.6" # from the libcudss.so version
KEYWORDS="~amd64 ~arm64 ~amd64-linux ~arm64-linux"
RESTRICT="mirror bindist test"

RDEPEND="
	=dev-util/nvidia-cuda-toolkit-12*
"

QA_PREBUILT="/opt/cuda*/targets/*-linux/lib/*"

src_configure() {
	:
}

src_compile() {
	:
}

src_install() {
	local narch
	if use amd64; then
		narch="x86_64"
	elif use arm64; then
		narch="sbsa"
	fi

	# allow slotted install
	local CUDNN_PATH="${CUDNN_PATH:-${EPREFIX}/opt/cuda}"

	cd "${WORKDIR}/libcudss-linux-${narch}-${PV}_cuda12-archive" || die

	dodir "${CUDNN_PATH}/targets/${narch}-linux"
	mv \
		include lib \
		"${ED}${CUDNN_PATH}/targets/${narch}-linux" \
		|| die

	# Add include and lib symlinks
	dosym -r "${CUDNN_PATH}/targets/${narch}-linux/include" "${CUDNN_PATH}/include"
	dosym -r "${CUDNN_PATH}/targets/${narch}-linux/lib" "${CUDNN_PATH}/$(get_libdir)"

	find "${ED}/${CUDNN_PATH}" -empty -delete || die
}