# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake xdg

DESCRIPTION="KeePassXC - KeePass Cross-platform Community Edition"
HOMEPAGE="https://keepassxc.org"
COMMIT="81e1e894b3e04b8f2bd743107fe6ca164218675d"
SRC_URI="https://github.com/the-nic/${PN}/archive/${COMMIT}.tar.gz -> ${P}.gh.tar.gz"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"

# COPYING order
LICENSE="|| ( GPL-2 GPL-3 ) BSD LGPL-2.1 MIT LGPL-2 CC0-1.0 Apache-2.0 GPL-2+ BSD-2"
SLOT="0"
IUSE="browser doc +keyring +network +ssh-agent test"

RESTRICT="!test? ( test )"

RDEPEND="
	app-crypt/argon2:=
	dev-libs/botan:3=
	dev-libs/libusb:1
	dev-libs/zxcvbn-c
	dev-qt/qtbase:6[concurrent,dbus,gui,network,widgets]
	dev-qt/qtsvg:6
	media-gfx/qrencode:=
	sys-apps/pcsc-lite
	sys-libs/readline:0=
	virtual/minizip:=
"
DEPEND="
	${RDEPEND}
"
BDEPEND="
	dev-qt/qttools:6
	doc? (
		dev-ruby/asciidoctor
	)
"

PATCHES=(
	"${FILESDIR}/${PN}-2.7.10-tests.patch"
	"${FILESDIR}/${PN}-2.7.10-zxcvbn.patch"
)

S="${WORKDIR}/${PN}-${COMMIT}"

src_prepare() {
	# Unbundle zxcvbn, bug 958062
	rm -r ./src/thirdparty/zxcvbn || die

	cmake_src_prepare
}

src_configure() {
	local -a mycmakeargs=(
		# Gentoo users enable ccache via e.g. FEATURES=ccache or
		# other means. We don't want the build system to enable it for us.
		-DWITH_CCACHE="OFF"
		-DWITH_GUI_TESTS="OFF"
		-DWITH_X11="OFF"
		-DKPXC_FEATURE_UPDATES="OFF"

		-DWITH_TESTS="$(usex test)"
		-DKPXC_FEATURE_BROWSER="$(usex browser)"
		-DKPXC_FEATURE_DOCS="$(usex doc)"
		-DKPXC_FEATURE_FDOSECRETS="$(usex keyring)"
		-DKPXC_FEATURE_NETWORK="$(usex network)"
		-DKPXC_FEATURE_SSHAGENT="$(usex ssh-agent)"
	)

	cmake_src_configure
}