# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games eutils fdo-mime

DESCRIPTION="Arrange the balls on the screen so that no lines cross"
HOMEPAGE="http://www.iki.fi/juri/caboodle/"
SRC_URI="http://www.helsinki.fi/~pakaste/store/dl/$PN/releases/$P.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND=">=x11-libs/gtk+-2.0
	x11-libs/cairo"
DEPEND="${RDEPEND}
	>=dev-ml/lablgtk-2.4.0_p20050701
	dev-ml/cairo-ocaml
	dev-lang/ocaml"

pkg_setup() {
	if ! built_with_use dev-ml/lablgtk glade; then
		eerror "lablgtk is missing glade support."
		eerror "Please add 'glade' to your USE flags, and re-emerge lablgtk."
		die "lablgtk needs glade support"
	fi
}

src_unpack() {
	unpack $P.tar.gz; cd ${S}
	sed -e "s!share\(/${PN}/${PN}.glade\)!share/games/\1!" -i src/$PN.ml
	sed -e '/update-desktop-database/d' -i Makefile
}

src_install() {
	make \
		PREFIX="${D}${GAMES_PREFIX}" \
		DESKTOPLOCATION="${D}/usr/share/applications" \
		install || die "make install failed"

	sed -e "s!${D}!!;s!${GAMES_PREFIX}/share!${GAMES_DATADIR}!" \
		-i ${D}/usr/share/applications/${PN}.desktop
		
	dodir "${GAMES_DATADIR}"
	mv "${D}${GAMES_PREFIX}/share/${PN}" "${D}${GAMES_DATADIR}/"
	rmdir "${D}${GAMES_PREFIX}/share"
	
	dodoc NEWS README
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}