# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI="6"

inherit meson gnome2-utils vala xdg-utils

DESCRIPTION="Find and listen to internet radio stations"
HOMEPAGE="https://github.com/haecker-felix/gradio"
SRC_URI="https://github.com/haecker-felix/gradio/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"

RDEPEND="
	dev-db/sqlite
	dev-libs/glib:2
	>=dev-libs/json-glib-1.0
	media-libs/gstreamer:1.0
	media-libs/gst-plugins-base:1.0
	media-plugins/gst-plugins-soup:1.0
	media-plugins/gst-plugins-hls:1.0
	>=net-libs/libsoup-2.4
	>=x11-libs/gtk+-3.22:3
"

DEPEND="${RDEPEND}
	$(vala_depend)
	>=dev-util/meson-0.42.0
"

src_prepare() {
	default
	vala_src_prepare
}

pkg_preinst() {
	gnome2_schemas_savelist
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_schemas_update
	gnome2_icon_cache_update
	xdg_desktop_database_update
}

pkg_postrm() {
	gnome2_schemas_update
	gnome2_icon_cache_update
	xdg_desktop_database_update
}