# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit qmake-utils udev gnome2-utils

DESCRIPTION="Signet is a free and open source software and open hardware USB storage and encryption device that also acts as a password manager."
HOMEPAGE="https://nthdimtech.com/signet/"
SRC_URI="https://nthdimtech.com/downloads/signet-releases/sources/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

COMMON_DEPEND="
	dev-qt/qtcore:5
	dev-qt/qtgui:5=
	dev-qt/qtwidgets:5
	dev-qt/qtnetwork:5
	dev-qt/qtwebsockets:5
	dev-qt/qtconcurrent:5
	dev-libs/libgcrypt:0
	dev-libs/libgpg-error
	x11-libs/libX11
	sys-libs/zlib
"
DEPEND="${COMMON_DEPEND}"

RDEPEND="${COMMON_DEPEND}"

src_prepare() {

	default

	echo -e "target.path = /usr/bin\nINSTALLS += target\n" \
		>> client/client.pro
}

src_configure() {
	eqmake5 client/client.pro
}

src_install() {
	emake INSTALL_ROOT="${D}" install
	einstalldocs
	
	udev_dorules ${FILESDIR}/50-signet.rules

	local i
    for i in 16x16 32x32 64x64 128x128 256x256 512x512; do
        newicon -s ${i} client/images/signet.iconset/icon_${i}.png ${PN}.png
    done
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}