# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

RPM_COMPRESS_TYPE="xz"
inherit desktop rpm xdg

DESCRIPTION="Official ChatGPT desktop application from OpenAI"
HOMEPAGE="https://chatgpt.com/ https://learn.chatgpt.com/docs/linux/linux-app"
SRC_URI="https://persistent.oaistatic.com/codex-app-prod/linux/rpm/x86_64/chatgpt-${PV}-1.x86_64.rpm -> ${P}.rpm"
S="${WORKDIR}"

LICENSE="all-rights-reserved"
SLOT="0"
KEYWORDS="-* ~amd64"

RDEPEND="
	app-accessibility/at-spi2-core:2
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/libusb:1
	dev-libs/nspr
	dev-libs/nss
	dev-vcs/git
	media-libs/alsa-lib
	media-libs/fontconfig
	media-libs/libglvnd[X]
	media-libs/mesa
	net-print/cups
	sys-apps/dbus
	sys-libs/glibc
	virtual/libudev
	x11-libs/cairo
	x11-libs/gdk-pixbuf:2
	x11-libs/gtk+:3
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXrandr
	x11-libs/libxcb
	x11-libs/libdrm
	x11-libs/libxkbcommon
	x11-libs/pango
	x11-misc/xdg-utils
"

RESTRICT="bindist mirror strip"

QA_PREBUILT="opt/chatgpt/*"

src_install() {
	dodir /opt
	cp -a "${S}/usr/lib/chatgpt" "${ED}/opt/" || die

	dobin "${FILESDIR}/chatgpt"
	domenu "${S}/usr/share/applications/chatgpt.desktop"
	doicon "${S}/usr/share/pixmaps/chatgpt.png"
	dodoc "${S}/usr/share/doc/chatgpt/copyright"
	dodoc "${FILESDIR}/environment.example"
}

pkg_postinst() {
	xdg_pkg_postinst

	elog "Optional per-user settings are sourced from:"
	elog "  ~/.config/chatgpt/environment"
	elog "See /usr/share/doc/${PF}/environment.example* for available settings."
	elog "For example, select a proxy per invocation with:"
	elog "  CHATGPT_PROXY_SERVER=socks5://127.0.0.1:9150 chatgpt"
	elog "An explicitly empty CHATGPT_PROXY_SERVER disables proxy use."
}

pkg_postrm() {
	xdg_pkg_postrm
}