# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{10..13} )
inherit meson python-any-r1 xdg

DESCRIPTION="Image viewer and browser from the X-Apps project"
HOMEPAGE="https://github.com/linuxmint/pix"
SRC_URI="https://github.com/linuxmint/pix/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="colord exiv2 gstreamer heif jxl lcms raw rsvg tiff webp"

RDEPEND="
	dev-libs/glib:2
	gnome-base/gsettings-desktop-schemas
	media-libs/libjpeg-turbo:=
	media-libs/libpng:0=
	x11-libs/gtk+:3
	x11-libs/xapp:=
	colord? ( x11-misc/colord:= )
	exiv2? ( media-libs/gexiv2:= )
	gstreamer? (
		media-libs/gstreamer:1.0
		media-libs/gst-plugins-base:1.0
		media-libs/gst-plugins-good:1.0
	)
	heif? ( media-libs/libheif:= )
	jxl? ( media-libs/libjxl:= )
	lcms? ( media-libs/lcms:2 )
	raw? ( media-libs/libraw:= )
	rsvg? ( gnome-base/librsvg:2 )
	tiff? ( media-libs/tiff:= )
	webp? ( media-libs/libwebp:= )
"

DEPEND="${RDEPEND}"

BDEPEND="
	${PYTHON_DEPS}
	dev-util/itstool
	sys-devel/gettext
	virtual/pkgconfig
"

src_configure() {
	local emesonargs=(
		$(meson_use colord)
		$(meson_use exiv2)
		$(meson_use gstreamer)
		$(meson_use heif libheif)
		$(meson_use jxl libjxl)
		$(meson_use lcms lcms2)
		$(meson_use raw libraw)
		$(meson_use rsvg librsvg)
		$(meson_use tiff libtiff)
		$(meson_use webp libwebp)
		-Dclutter=false
		-Dlibchamplain=false
		-Dwebservices=false
		-Dlibbrasero=false
	)
	meson_src_configure
}