# Copyright 2026 Nadeŭka <me+oss@nadevko.cc>
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit fcaps meson xdg

DESCRIPTION='Fullscreen overlay UI for GPU Screen Recorder in the style of ShadowPlay'
HOMEPAGE=https://git.dec05eba.com/gpu-screen-recorder-ui/about
SRC_URI="https://dec05eba.com/snapshot/${PN}.git.${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}"
LICENSE='CC-BY-4.0 CC-BY-SA-3.0 CC0-1.0 GPL-3'

SLOT=0
KEYWORDS=amd64
IUSE=+filecaps

COMMON_DEPEND='
	dev-libs/wayland
	media-libs/libglvnd
	media-libs/libpulse
	sys-apps/dbus
	sys-libs/libcap
	x11-libs/libdrm
	x11-libs/libX11
	x11-libs/libXcomposite
	x11-libs/libXcursor
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXi
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libxkbcommon
	x11-libs/pango
'
BDEPEND='
	dev-util/wayland-scanner
	sys-kernel/linux-headers
	virtual/pkgconfig
'
DEPEND="${COMMON_DEPEND}"
RDEPEND="
	${COMMON_DEPEND}
	>=gui-capture/gpu-screen-recorder-5
	gui-capture/gpu-screen-recorder-notification
"

FILECAPS=(
	cap_sys_admin+ep usr/bin/gsr-global-hotkeys
)

src_configure() {
	local emesonargs=(
		-Ddesktop-files=true
		-Dcapabilities=false
	)
	meson_src_configure
}

pkg_postinst() {
	xdg_pkg_postinst
	use filecaps && fcaps_pkg_postinst
}