# Copyright 2026 Nadeŭka <me+oss@nadevko.cc>
# Distributed under the terms of the GNU General Public License v2
EAPI=8

inherit udev

DESCRIPTION='A program to read and control device brightness'
HOMEPAGE=https://github.com/Hummer12007/brightnessctl
SRC_URI="$HOMEPAGE/archive/refs/tags/$PV.tar.gz -> $P.tar.gz"
LICENSE=MIT
SLOT=0
KEYWORDS='amd64 ~arm ~arm64 ~ppc64 ~x86'

IUSE='systemd +udev'

BDEPEND=virtual/pkgconfig
DEPEND='systemd? ( >=sys-apps/systemd-243 )'
RDEPEND="
	$DEPEND
	udev? ( virtual/udev acct-group/video acct-group/input )
"

src_prepare() {
	default
	sed -i \
		's|install: all \${INSTALL_UDEV_\${INSTALL_UDEV_RULES}}|install:|' \
		Makefile || die 'failed to patch Makefile'
}

src_install() {
	emake DESTDIR="$D" \
		$(usev systemd 'ENABLE_SYSTEMD=1') \
		UDEVDIR="$(get_udevdir)" \
		install $(usev udev install_udev_rules)
	newinitd "$FILESDIR/brightnessctl.initd" brightnessctl
	newconfd "$FILESDIR/brightnessctl.confd" brightnessctl
}

pkg_postinst() {
	use udev && udev_reload

	elog 'To make brightness persistent across reboots on OpenRC,'
	elog 'enable the service:'
	elog '  rc-update add brightnessctl boot'
	elog '  rc-service brightnessctl start'
}

pkg_postrm() {
	use udev && udev_reload
}