# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit readme.gentoo-r1 toolchain-funcs

DESCRIPTION="Utility to detect other OSs on a set of drives"
HOMEPAGE="https://packages.debian.org/source/sid/os-prober"
SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${PN}_${PV}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

# grub-mount needed per bug #607518
RDEPEND="sys-boot/grub:2[mount]"
DEPEND=""

# bug 594250
QA_MULTILIB_PATHS="usr/lib/os-prober/.*"

# start : Redcore Linux Project tweaks
PATCHES=(
	${FILESDIR}/${PN}-newnsdirfix.patch
	${FILESDIR}/${PN}-SUSE.patch
	${FILESDIR}/${PN}-1.49-fix-grub2.cfg-parsing.patch
	${FILESDIR}/${PN}-1.49-grub2-mount.patch
	${FILESDIR}/${PN}-probe-MD-devices.patch
	${FILESDIR}/${PN}-linux-secure-boot.patch
	${FILESDIR}/${PN}-btrfsfix.patch
	${FILESDIR}/${PN}-EFI-openSUSEfy.patch
	${FILESDIR}/${PN}-accept-ESP-on-IMSM.patch
	${FILESDIR}/${PN}-dont-load-all-fs-module-and-dont-test-mount.patch
	${FILESDIR}/${PN}-fix-btrfs-subvol-mounted-tests.patch
	${FILESDIR}/${PN}-skip-part-on-multipath.patch
	${FILESDIR}/Improve-btrfs-handling-on-os-probing-for-grub2.patch
	${FILESDIR}/${PN}-btrfs-absolute-subvol.patch
	${FILESDIR}/${PN}-40grub-check-grub2.patch
	${FILESDIR}/${PN}-btrfs-snapshot-detection.patch
	${FILESDIR}/${PN}-btrfs-always-detect-default.patch
	${FILESDIR}/${PN}-linux-distro-avoid-expensive-ld-file-test.patch
	${FILESDIR}/${PN}-linux-distro-parse-os-release.patch
	${FILESDIR}/${PN}-05efi-blkid.patch
	${FILESDIR}/${PN}-multiple-initrd.patch
	${FILESDIR}/${PN}-make-btrfsprogs-optional.patch
	${FILESDIR}/${PN}-use-tmp-over-var-lib-for-transient-files.patch
	${FILESDIR}/${PN}-btrfs-multiple-device.patch
	${FILESDIR}/${PN}-redcore.patch
)
# stop : Redcore Linux Project tweaks

DOC_CONTENTS="
	If you intend for os-prober to detect versions of Windows installed on
	NTFS-formatted partitions, your system must be capable of reading the
	NTFS filesystem. One way to do this is by installing sys-fs/ntfs3g
"

src_prepare() {
	default
	# use default GNU rules
	rm Makefile || die 'rm Makefile failed'
}

src_compile() {
	tc-export CC
	emake newns
}

src_install() {
	dobin os-prober linux-boot-prober

	# Note: as no shared libraries are installed, /usr/lib is correct
	exeinto /usr/lib
	doexe newns

	insinto /usr/share/os-prober
	doins common.sh

	keepdir /var/lib/os-prober

	local debarch=${ARCH%-*} dir

	case ${debarch} in
		amd64)		debarch=x86 ;;
		ppc|ppc64)	debarch=powerpc ;;
	esac

	for dir in os-probes{,/mounted,/init} linux-boot-probes{,/mounted}; do
		exeinto /usr/lib/${dir}
		doexe ${dir}/common/*
		if [[ -d ${dir}/${debarch} ]]; then
			doexe ${dir}/${debarch}/*
		fi
		if [[ -d ${dir}/${debarch}/efi ]]; then
			exeinto /usr/lib/${dir}/efi
			doexe ${dir}/${debarch}/efi/*
		fi
	done

	if use amd64 || use x86; then
		exeinto /usr/lib/os-probes/mounted
		doexe os-probes/mounted/powerpc/20macosx
	fi

	einstalldocs
	dodoc debian/changelog

	readme.gentoo_create_doc
}

pkg_postinst() {
	readme.gentoo_print_elog
}